Whatsup - לינוקס, תוכנה חופשית וקוד פתוח בעברית

קבצים והתקנות - [נפתר] הידור אורייתא בארצ'לינוקס עם QT5
yoelion - 16/09/2015 - 14:09
נושא ההודעה: [נפתר] הידור אורייתא בארצ'לינוקס עם QT5
היי.

אני מנסה לשכתב מחדש PKGBUILD לאורייתא בארץ' ללא הצלחה. עשיתי המון ניסויים. כן, ניסיתי לתאם את קובץ pro ולכפות עליו. הנה קובץ PKGBUILD למי שרוצה לעזור לי לתקן את תהליך הבנייה:

קוד:
pkgname=orayta-svn
pkgver=776
pkgrel=1
pkgdesc="Jewish books program with Hebrew & French translations"
arch=('i686' 'x86_64')
license=('GPLv3')
url="http://code.google.com/p/orayta/"
depends=('fribidi' 'qt5-webkit')
makedepends=('qt5-base' 'subversion')
conflicts=('quazip')
optdepends=('ttf-dejavu: good for Hebrew fonts'
            'culmus: better for Hebrew fonts'
            'ttf-sbl-hebrew: a biblical Hebrew fonts'
            'ttf-sil-ezra: a another Hebrew fonts')
_svntrunk=http://orayta.googlecode.com/svn/trunk/
_svnmod=orayta
build() {
  if [[ -d "$_svnmod/.svn" ]]; then
    (cd "$_svnmod" && svn up -r "$pkgver")
  else
svn co $_svntrunk $_svnmod
fi
  msg "SVN checkout done or server timeout"
  msg "Starting make..."
cd $srcdir/$_svnmod
sed -i '36,39d' Orayta.pro
qmake-qt5 \
    PREFIX=$pkgdir/usr \
    CONFIG+=linux
   #QMAKE_CFLAGS_RELEASE+=${CFLAGS} ${CPPFLAGS}\
   #QMAKE_CFLAGS_DEBUG+=${CFLAGS} ${CPPFLAGS}
   #QMAKE_CXXFLAGS_RELEASE+=${CFLAGS} ${CPPFLAGS}\
   #QMAKE_CXXFLAGS_DEBUG+=${CFLAGS}\
   #QMAKE_CXXFLAGS_DEBUG+=${CPPFLAGS}

make
}

package() {
make INSTALL_ROOT=${pkgdir} install
}
חתול - 16/09/2015 - 15:30
נושא ההודעה:
השגיאה העיקרית שאני רואה היא: fatal error: QPrinter: No such file or directory
וזה נפתר אם מוסיפים לקובץ Orayta.pro את השורה:
קוד:
QT += printsupport


בנוסף כדאי להסיר את הדגלים dpkg-buildflags שגורמים להרבה שגיאות.

זה עדיין לא מתהדר אבל זו התחלה.
yoelion - 16/09/2015 - 15:47
נושא ההודעה:
תודה, חתול. מה החלופה לפקודת dpkg*? אם מורידים הערה מהגדרות qmake ב־PKGBUILD, הפקודה QMAKE מחזיר עצות. צריך שינויים מהותיים ולא נקודתיים
Anonymous - 17/09/2015 - 13:47
נושא ההודעה:
yoelion :
תודה, חתול. מה החלופה לפקודת dpkg*? אם מורידים הערה מהגדרות qmake ב־PKGBUILD, הפקודה QMAKE מחזיר עצות. צריך שינויים מהותיים ולא נקודתיים


יכול להיות שזה לא עובד לך בגלל שאתה לא מכוון את התוכנה לצאת ידי חובה כשהיא מתהדרת.
Very Happy
Anonymous - 17/09/2015 - 21:16
נושא ההודעה:
תנסה לקמפל לפי דרבנן.
משה - 18/09/2015 - 12:40
נושא ההודעה:
אוקיי, נתחיל מההתנצלות.

חלפו כמה וכמה שנים מאז שהתחלתי לפתח את אורייתא, וכרגע אני בשלב בו אני מנסה איכשהו לשלב בין עבודה ללימודי הנדסה - ככה שהזמן שלי לפתח את אורייתא באופן כללי שואף לאפס.

בנוסף, כמות משתמשי הדסקטופ (ובפרט בלינוקס), למעשה די זניחה ביחס למשתמשי גרסת האנדרואיד. היחס הוא של משהו כמו שלושה סדרי גודל. כמובן שהאיכות היא פקטור, אבל הכמות...

Having that said, אין שום סיבה שגרסת הדסקטופ לא תמשיך לעבוד, גם אם הקוד שלה מתוחזק רק מינימלית.
אין לי ארץ' מותקן כרגע (שוב, טרדות הזמן), אבל על פניו הבעייה היא המעבר ל Qt5, ואכן ה flag שחתול דיבר עליו הוא זה שהיה חסר.

עידכנתי את הקובץ ש qmake משתמש בו, וכעת זה אמור לעבוד. כל מה שצריך זה qmake (או qmake-qt5) ואז make ו- make install.

בכל מקרה, וזה החלק הכי קריטי בתשובה, googlecode די נסגר. הקוד האמיתי יושב כאן:
https://github.com/MosheWagner/Orayta-QT
צריך לעדכן זאת בקובץ ה PKGBUILD, כמובן, ולהחליף את סוג המאגר ל git.

מקווה שעכשיו זה יעבוד.

שנה טובה!
OhadEytan - 19/09/2015 - 22:43
נושא ההודעה:
תודה למשה על הפיתוח
וליואל על הPKGBUILD לארץ'
חתול - 21/09/2015 - 10:49
נושא ההודעה:
ניסיתי לבנות ממאגר הגיט והבנייה נכשלת בהודעה
קוד:
make: *** No rule to make target 'install'.  Stop
yoelion - 22/09/2015 - 10:35
נושא ההודעה:
2 ה־PKGBUILDS:

קוד:
# Maintainer: Yoel Lion <yoel3ster at gmail dot com>

_pkgname=Orayta-QT
pkgname=orayta
pkgver=r99.a5570d4
pkgrel=1
pkgdesc="Jewish books program with Hebrew & French translations"
arch=('i686' 'x86_64')
license=('GPLv3')
url="http://code.google.com/p/orayta/"
depends=('fribidi' 'qt5-webkit' 'orayta-books')
makedepends=('qt5-base' 'git')
conflicts=('quazip' 'orayta-svn')
optdepends=('ttf-dejavu: good for Hebrew fonts'
            'culmus: better for Hebrew fonts'
            'ttf-sbl-hebrew: a biblical Hebrew fonts'
            'ttf-sil-ezra: a another Hebrew fonts')
source=(git+https://github.com/MosheWagner/Orayta-QT.git)
md5sums=('SKIP')

pkgver() {
  cd "$_pkgname"
  ( set -o pipefail
    git describe --long | sed -r 's/([^-]*-g)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}
build() {
cd $srcdir/$_pkgname
qmake-qt5 PREFIX=/usr
make
}

package() {
cd $srcdir/$_pkgname
make INSTALL_ROOT=${pkgdir} install
}


קוד:
# Maintainer: Yoel Lion <yoel3ster at gmail dot com>

_pkgname=Orayta-Books
pkgname=orayta-books
pkgver=r2.4214f16
pkgrel=1
pkgdesc="Orayta books"
arch=('any')
license=('CC-BY-3.0')
url="http://code.google.com/p/orayta/"
makedepends=('git')
conflicts=('orayta-books-svn')
source=(git+https://github.com/MosheWagner/Orayta-Books.git)
md5sums=('SKIP')

pkgver() {
  cd "$_pkgname"
  ( set -o pipefail
    git describe --long | sed -r 's/([^-]*-g)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

build() {
cd $srcdir/$_pkgname/books
./GenMakeFile.sh
}

package() {
cd $srcdir/$_pkgname/books
make DESTDIR=$pkgdir install
}
yoelion - 22/09/2015 - 10:43
נושא ההודעה:
כן, לא העליתי ל־AUR. בינתיים אני כישלון מוחלט בתחום ה־SSH.

גמר חתימה טובה
yoelion - 22/09/2015 - 13:04
נושא ההודעה:
העליתי
כל הזמנים הם GMT + 2 שעות